teilchensammler-cli/justfile

default:
  @just --list

setup:
  uv sync

# run Textual's console
console:
  uv run textual console

the_app := "teilchensammler_cli.main"

# run app with logs going to console
run-dev:
  uv run textual run --dev {{ the_app }}

run:
  uv run python -m {{ the_app }}

uv_export_options := "--frozen --format requirements.txt --quiet --no-install-project"
exports-deps:
  uv export {{ uv_export_options }} --output-file requirements.txt
  uv export {{ uv_export_options }} --output-file requirements.dev.txt --only-dev

install-deps: setup

update-deps:
  uv lock --upgrade
  uv sync

test *ARGS:
  uv run pytest tests.py {{ ARGS }}

coverage:
  uv run pytest tests.py --cov=src/ --cov-report term --cov-report xml --cov-report html --cov-config pyproject.toml

lint-python:
  uv run ruff check .

lint-markdown:
  markdownlint-cli2 .

lint: lint-python lint-markdown

# remove artefacts from dist/
clean:
  rm dist/*.whl dist/*.tar.gz

ci: lint
  prek run --all-files
#   woodpecker-cli exec "whatever"

release:
  @echo remember to git tag and update pyproject.toml
  uv build
  # upload to package registry
  # send newsletter
  # take over the world